While examining the XP progression (Slow, Medium, Fast), I tried to come up with an Excel Formula for them... Alas, there does not seem to be any logic behind those progressions.
Am I missing something, or is the XP progression just a random increase of number at each levels?! (unlike D&D3.5 where the progression can be evaluated by a simple mathematical formula...)
RiTz21
http://TheOnlySheet.com
There's rounding being done, as I understand it, but the overall formulas are all "X encounters of character's level CR to reach next level, assuming a 4-member party with equal XP shares", with 13.33 for the fast, 20 for the medium, and 30 for the slow.
The XP per CR follows the pattern:
1X, 1.5X, 2X, 3X, 4X, 6X, 8X, 12X, 16X . . .
So each odd CR is twice the last odd CR, each even CR is 1.5 times the last odd CR, each even CR is twice the last even CR, and each odd CR is 1&1/3 times the last even CR.
Its not a formula. As I recall it is either 13, 20, or 30 encounters of a level equal to your present level to reach the next level. If you check the amount of xp necessary to increase a level, then divide that number by the amount of experience a character will recieve for an encounter of his own level, you should get about 13 for fast, 20 for medium, and 30 for slow progression. That is, if it hasn't changed since I did the math after Alpha 1.
Paizo had to come up with a new set of totals as the one we have been using was not open gaming license.
edit: Read previous post, as said it better than I did. And gave more details.
| 1 person marked this as a favorite. |
Ask and ye shall receive! If cell A1 contains an integer from 1-20, then:
=ROUND((2000 * (2^FLOOR(A1/2;1) - 1) + 3000 * (2^FLOOR((A1-1)/2;1) - 1))/10^(FLOOR(SQRT(A1-1);1)+1)*2)/2*10^(FLOOR(SQRT(A1-1);1)+1)
is exactly the number of XP needed to attain that level on the Medium chart. Note: this is an OpenOffice Calc formula, but it's easy enough to convert it to an Excel formula.
Fast = Medium/1.5 (rounded)
Slow = Medium*1.5 (rounded)
The rounding does, indeed, seem to be the issue. Sometimes they allow three significant figures, sometimes only two. I guess that is where consistency should be important.
They allow "2.5" significant figures (sort of). So you need to multiply by two before you round, then divide by two after.
The fast chart is the 3.x standard advancement rate, but hidden behind new numbers. The reason the 3.x XP system isn't used is because it isn't Open Content.
=ROUND((2000 * (2^FLOOR(A1/2;1) - 1) + 3000 * (2^FLOOR((A1-1)/2;1) - 1))/10^(FLOOR(SQRT(A1-1);1)+1)*2)/2*10^(FLOOR(SQRT(A1-1);1)+1)
is exactly the number of XP needed to attain that level on the Medium chart. Note: this is an OpenOffice Calc formula, but it's easy enough to convert it to an Excel formula.
Hell of a job figuring out the equation to that. I actually gave up and was surprised to see it was doable. Good job!
For those of You using Excel, here's the version You'd use for Medium:
=ROUND((2000 * (2^FLOOR(A1/2,1) - 1) + 3000 * (2^FLOOR((A1-1)/2,1) - 1))/10^(FLOOR(SQRT(A1-1),1)+1)*2,0)/2*10^(FLOOR(SQRT(A1-1),1)+1)
I'm sure this was discussed before . . . but because I'm ignorant, I'll ask it again: Why not just use the standard advancement formula . . . at least as a base for medium and slow advancement? Or turn the standard advancement as the medium.
Paizo had to come up with a new set of totals as the one we have been using was not open gaming license.
Wow nice formula hogarth! It works perfectly for the Medium progression! THANKS!
For the Slow = Medium*1.5 (rounded), this seems to break down starting at level 9.
Level 8 (Medium): 51,000 * 1.5 = 76,500, which can be rounded to 77,000 - the correct value.
Yet:
Level 9 (Medium): 75,000*1.5 = 112,500, which can be rounded to 113,000 - which is incorrect as the "slow" value for level 9 is 115,000 !
The same goes for the next levels...
I wish the progression would have been more Logical...!
RiTz
|
In all of my games from now on I am dropping the progression charts all together. Someone on here had a brilliant idea (wish I could give credit).
1000 xp per level
each encounter is awarded xp appropriate to the number of encounters you wnt to use for leveling. Suggested xp awards per encounter are
EL-2 50
EL-1 75
EL - 100
EL+1 125
EL+2 150
You want to progress faster then award extra xp. You want to progress slower, award less xp.
This system is much more elegant and versitile than three progression charts.
With three charts, let's say you want to shoot through levels one-three so you use the fast chart. But you want to go normal for levels 5&6, so you have to have everyone recalculate their XP according to the medium chart. You want to power through level 7 so everyone recalculates their XP to the fast chart again. For levels 8-12 you want to go slow as that is the meat of the story, so everyone once again recalculates their xp.
This is the silliest idea I have ever seen. The above scenario is not outrageous at all, but it requires players to recalculate three times. Why in the world would you want your players recalculating their xp?
Doesn't it makes sense instead for the DM to just award more or less xp based upon the situation?
Well, in the end, the system is made so that you go up one level every so many encounters, depending on which speed you chose:
Fast --> Go up one level after +-13 Encounters of your ECL (i.e. like 3.5)
Medium --> Go up one level after +-20 Encounters of your ECL
Slow --> Go up one level after +-30 Encounters of your ECL
It does not change when you go up in level. Wherever you are along the level progression chart of "your" progression speed, it always takes +- the same number of level-appropriate encounters to go up one level.
I would have preferred a system which not only allows you to choose between fast, medium and slow, but also where the progression slows down as you go up in level. Here it is not the case.
Bocklin
Hogarth, as RiTz has said, your formula works great for the medium progression, but would you help in coming up with formulas for the fast and slow ones? The values are rather off when multiplied by 1.5 or divided by 1.5, even after rounding.
Yes, I noticed. It's a matter of sometimes rounding up, sometimes rounding down, sometimes rounding to the nearest "1", sometimes rounding to the nearest "0.5", etc.
For an Excel spreadsheet, using a VLOOKUP is simple enough of course.
For an Excel spreadsheet, using a VLOOKUP is simple enough of course.
True enough - or the CHOOSE() function for that matter (which don't even require a table!). I am aware of the possible 'work arounds'. But still, the progression (in my humble opinion) should not be a random thing, as it seems to be at the moment!
If a game master decided to go beyond level 20, a CHOOSE() would not be useful, and a VLOOKUP() would require an expended table...
Had the progression been a formula (as in D&D3.5) then it would have been rather simple to know the XP required for a 39th level character... Or 97th for that matter!
Let's hope the designer revises his progression to make it follow a reproducible progression.... <crossing finders>
RiTz21
http://TheOnlySheet.com
The rounding does, indeed, seem to be the issue. Sometimes they allow three significant figures, sometimes only two. I guess that is where consistency should be important.They allow "2.5" significant figures (sort of). So you need to multiply by two before you round, then divide by two after.
Going by this I get:
Fast: =ROUND(2*A1/1.5,-LOG(2*A1/1.5)+1)/2& Slow: =ROUND(3*A1,-LOG(3*A1)+1)/2
Fast is off at 2nd, 3rd, 6th, 7th, & 10th
Slow is off at 4th - 8th, 14th, 15th, 17th, & 20th
Some of the "off" is weirdness in the table, some from odd rounding.
39th level: 3,950,000,000 2,620,000,000 1,750,000,000
97th level: 2,100,000,000,000,000,000 1,407,374,885,000,000,000 950,000,000,000,000,000
[That's 2.1 Quintillion for Slow at 97th level).
I looked at it a bit differently. Here's the formulas I had:
"Fast"
=ROUND((3000 * (2^FLOOR(A1/2,1) - 1) + 4500 * (2^FLOOR((A1-1)/2,1) - 1))/10^(FLOOR(SQRT(A1-1),1)+1)*2,0)/2*10^(FLOOR(SQRT(A1-1),1)+1)
This is off at levels 4-8 (which are rounded up to the nearest 1000), perfect otherwise.
"Slow"
=ROUND((1333 * (2^FLOOR(A1/2,1) - 1) + 2000 * (2^FLOOR((A1-1)/2,1) - 1))/10^(FLOOR(SQRT(A1-1),1)+1)*2,0)/2*10^(FLOOR(SQRT(A1-1),1)+1)
This is complicated by the fact that Jason rounded "1/3" down to "0" sometimes (levels 2, 3, 6, 7, and 10) and up to "1/2" sometimes (levels 11, 14, 15, 18, and 19). Also, level 16 is rounded up to the nearest 100K instead of 50K.